0 BEGIN PGM 9040_IT MM 
1 ;Programma NC per determinare automaticamente il nome
2 ;del file e incidere mediante ciclo sul pezzo.
3 ;Il controllo numerico legge con una funzione stringa con
4 ;ID corrispondente il percorso del programma e lo salva
5 ;in QS1. In seguito richiama un altro programma
6 ;selezionando il nome del file nel percorso.
7 ;Trasferisce quindi di nuovo il nome del file nel parametro
8 ;stringa QS1 del programma chiamante. Lo utilizza poi come
9 ;testo da incidere nel ciclo 225.
10 ;Se i file impiegati non si trovano nella stessa directory,
11 ;è necessario adattare le indicazioni del percorso nella
12 ;chiamata.
13 ;
14 BLK FORM 0.1 Z X+0 Y+0 Z-20
15 BLK FORM 0.2  X+100  Y+100  Z+0
16 ;
17 ;Chiamata utensile per incidere
18 TOOL CALL 151 Z S10000
19 ;
20 ;Disimpegno
21 L  Z+100 R0 FMAX M3
22 ;
23 ;Lettura del percorso del file con ID10010 NR1 e salvataggio
24 ;in QS1
QS1 = SYSSTR( ID10010 NR1 )
25 ;
26 ;Chiamata programma per la selezione del nome del file dal
27 ;percorso
28 CALL PGM 90401_it.H
29 ;
30 ;Incisione del nome del file che si trova in QS1
31 CYCL DEF 225 INCISIONE ~
   QS500= QS1     ;TESTO INCISIONE ~
    Q513=+8    ;ALTEZZA CARATTERE ~
    Q514=+0    ;FATTORE DISTANZA ~
    Q515=+0    ;TIPO FONT ~
    Q516=+0    ;DISPOSIZIONE TESTO ~
    Q374=+0    ;ANGOLO DI ROTAZIONE ~
    Q517=+50   ;RAGGIO CERCHIO ~
    Q207=+2000 ;AVANZAM. FRESATURA ~
    Q201=-0.1  ;PROFONDITA ~
    Q206=+150  ;AVANZ. INCREMENTO ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA
32 L  X+20  Y+40 R0 FMAX M99
33 ;
34 ;Disimpegno
35 L  Z+100 R0 FMAX
36 ;
37 ;Fine programma
38 M30
39 END PGM 9040_IT MM